| // Copyright 2022 The Go Authors. All rights reserved. |
| // Use of this source code is governed by a BSD-style |
| // license that can be found in the LICENSE file. |
| |
| // This file contains rules used by the laterLower pass. |
| |
| // Simplify ISEL x $0 z into ISELZ |
| (ISEL [a] x (MOVDconst [0]) z) => (ISELZ [a] x z) |
| // Simplify ISEL $0 y z into ISELZ by inverting comparison and reversing arguments. |
| (ISEL [a] (MOVDconst [0]) y z) => (ISELZ [a^0x4] y z) |
| |
| // SETBC, SETBCR is supported on ISA 3.1(Power10) and newer, use ISELZ for |
| // older targets |
| (SETBC [2] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [2] (MOVDconst [1]) cmp) |
| (SETBCR [2] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [6] (MOVDconst [1]) cmp) |
| (SETBC [0] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [0] (MOVDconst [1]) cmp) |
| (SETBCR [0] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [4] (MOVDconst [1]) cmp) |
| (SETBC [1] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [1] (MOVDconst [1]) cmp) |
| (SETBCR [1] cmp) && buildcfg.GOPPC64 <= 9 => (ISELZ [5] (MOVDconst [1]) cmp) |
| |
| // Avoid using ANDCCconst if the value for CR0 is not needed, since ANDCCconst |
| // always sets it. |
| (Select0 z:(ANDCCconst [m] x)) && z.Uses == 1 && isPPC64ValidShiftMask(m) => (RLDICL [encodePPC64RotateMask(0,m,64)] x) |
| // The upper bits of the smaller than register values is undefined. Take advantage of that. |
| (AND <t> x:(MOVDconst [m]) n) && t.Size() <= 2 => (Select0 (ANDCCconst [int64(int16(m))] n)) |
| |
| // Convert simple bit masks to an equivalent rldic[lr] if possible. |
| (AND x:(MOVDconst [m]) n) && isPPC64ValidShiftMask(m) => (RLDICL [encodePPC64RotateMask(0,m,64)] n) |
| (AND x:(MOVDconst [m]) n) && m != 0 && isPPC64ValidShiftMask(^m) => (RLDICR [encodePPC64RotateMask(0,m,64)] n) |
| |
| // If the RLDICL does not rotate its value, a shifted value can be merged. |
| (RLDICL [em] x:(SRDconst [s] a)) && (em&0xFF0000) == 0 => (RLDICL [mergePPC64RLDICLandSRDconst(em, s)] a) |
| |
| // Convert rotated 32 bit masks on 32 bit values into rlwinm. In general, this leaves the upper 32 bits in an undefined state. |
| (AND <t> x:(MOVDconst [m]) n) && t.Size() == 4 && isPPC64WordRotateMask(m) => (RLWINM [encodePPC64RotateMask(0,m,32)] n) |
| |
| // When PCRel is supported, paddi can add a 34b signed constant in one instruction. |
| (ADD (MOVDconst [m]) x) && supportsPPC64PCRel() && (m<<30)>>30 == m => (ADDconst [m] x) |
| |
| |
| // Where possible and practical, generate CC opcodes. Due to the structure of the rules, there are limits to how |
| // a Value can be rewritten which make it impossible to correctly rewrite sibling Value users. To workaround this |
| // case, candidates for CC opcodes are converted in two steps: |
| // 1. Convert all (x (Op ...) ...) into (x (Select0 (OpCC ...) ...). See convertPPC64OpToOpCC for more |
| // detail on how and why this is done there. |
| // 2. Rewrite (CMPconst [0] (Select0 (OpCC ...))) into (Select1 (OpCC...)) |
| // Note: to minimize potentially expensive regeneration of CC opcodes during the flagalloc pass, only rewrite if |
| // both ops are in the same block. |
| (CMPconst [0] z:((ADD|AND|ANDN|OR|SUB|NOR|XOR) x y)) && v.Block == z.Block => (CMPconst [0] convertPPC64OpToOpCC(z)) |
| (CMPconst [0] z:((NEG|CNTLZD) x)) && v.Block == z.Block => (CMPconst [0] convertPPC64OpToOpCC(z)) |
| // Note: ADDCCconst only assembles to 1 instruction for int16 constants. |
| (CMPconst [0] z:(ADDconst [c] x)) && int64(int16(c)) == c && v.Block == z.Block => (CMPconst [0] convertPPC64OpToOpCC(z)) |
| // And finally, fixup the flag user. |
| (CMPconst <t> [0] (Select0 z:((ADD|AND|ANDN|OR|SUB|NOR|XOR)CC x y))) => (Select1 <t> z) |
| (CMPconst <t> [0] (Select0 z:((ADDCCconst|NEGCC|CNTLZDCC) y))) => (Select1 <t> z) |
