| // Copyright 2009 The Go Authors. All rights reserved. |
| // Use of this source code is governed by a BSD-style |
| // license that can be found in the LICENSE file. |
| |
| #include "textflag.h" |
| #include "funcdata.h" |
| |
| // |
| // System calls for AMD64, Linux |
| // |
| |
| #define SYS_gettimeofday 96 |
| |
| // func Syscall(trap int64, a1, a2, a3 uintptr) (r1, r2, err uintptr); |
| // Trap # in AX, args in DI SI DX R10 R8 R9, return in AX DX |
| // Note that this differs from "standard" ABI convention, which |
| // would pass 4th arg in CX, not R10. |
| |
| TEXT ·Syscall(SB),NOSPLIT,$0-56 |
| CALL runtime·entersyscall(SB) |
| MOVQ a1+8(FP), DI |
| MOVQ a2+16(FP), SI |
| MOVQ a3+24(FP), DX |
| MOVQ trap+0(FP), AX // syscall entry |
| SYSCALL |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok |
| MOVQ $-1, r1+32(FP) |
| MOVQ $0, r2+40(FP) |
| NEGQ AX |
| MOVQ AX, err+48(FP) |
| CALL runtime·exitsyscall(SB) |
| RET |
| ok: |
| MOVQ AX, r1+32(FP) |
| MOVQ DX, r2+40(FP) |
| MOVQ $0, err+48(FP) |
| CALL runtime·exitsyscall(SB) |
| RET |
| |
| // func Syscall6(trap, a1, a2, a3, a4, a5, a6 uintptr) (r1, r2, err uintptr) |
| TEXT ·Syscall6(SB),NOSPLIT,$0-80 |
| CALL runtime·entersyscall(SB) |
| MOVQ a1+8(FP), DI |
| MOVQ a2+16(FP), SI |
| MOVQ a3+24(FP), DX |
| MOVQ a4+32(FP), R10 |
| MOVQ a5+40(FP), R8 |
| MOVQ a6+48(FP), R9 |
| MOVQ trap+0(FP), AX // syscall entry |
| SYSCALL |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok6 |
| MOVQ $-1, r1+56(FP) |
| MOVQ $0, r2+64(FP) |
| NEGQ AX |
| MOVQ AX, err+72(FP) |
| CALL runtime·exitsyscall(SB) |
| RET |
| ok6: |
| MOVQ AX, r1+56(FP) |
| MOVQ DX, r2+64(FP) |
| MOVQ $0, err+72(FP) |
| CALL runtime·exitsyscall(SB) |
| RET |
| |
| // func RawSyscall(trap, a1, a2, a3 uintptr) (r1, r2, err uintptr) |
| TEXT ·RawSyscall(SB),NOSPLIT,$0-56 |
| MOVQ a1+8(FP), DI |
| MOVQ a2+16(FP), SI |
| MOVQ a3+24(FP), DX |
| MOVQ trap+0(FP), AX // syscall entry |
| SYSCALL |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok1 |
| MOVQ $-1, r1+32(FP) |
| MOVQ $0, r2+40(FP) |
| NEGQ AX |
| MOVQ AX, err+48(FP) |
| RET |
| ok1: |
| MOVQ AX, r1+32(FP) |
| MOVQ DX, r2+40(FP) |
| MOVQ $0, err+48(FP) |
| RET |
| |
| // func RawSyscall6(trap, a1, a2, a3, a4, a5, a6 uintptr) (r1, r2, err uintptr) |
| TEXT ·RawSyscall6(SB),NOSPLIT,$0-80 |
| MOVQ a1+8(FP), DI |
| MOVQ a2+16(FP), SI |
| MOVQ a3+24(FP), DX |
| MOVQ a4+32(FP), R10 |
| MOVQ a5+40(FP), R8 |
| MOVQ a6+48(FP), R9 |
| MOVQ trap+0(FP), AX // syscall entry |
| SYSCALL |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok2 |
| MOVQ $-1, r1+56(FP) |
| MOVQ $0, r2+64(FP) |
| NEGQ AX |
| MOVQ AX, err+72(FP) |
| RET |
| ok2: |
| MOVQ AX, r1+56(FP) |
| MOVQ DX, r2+64(FP) |
| MOVQ $0, err+72(FP) |
| RET |
| |
| // func rawVforkSyscall(trap, a1 uintptr) (r1, err uintptr) |
| TEXT ·rawVforkSyscall(SB),NOSPLIT|NOFRAME,$0-32 |
| MOVQ a1+8(FP), DI |
| MOVQ $0, SI |
| MOVQ $0, DX |
| MOVQ $0, R10 |
| MOVQ $0, R8 |
| MOVQ $0, R9 |
| MOVQ trap+0(FP), AX // syscall entry |
| POPQ R12 // preserve return address |
| SYSCALL |
| PUSHQ R12 |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok2 |
| MOVQ $-1, r1+16(FP) |
| NEGQ AX |
| MOVQ AX, err+24(FP) |
| RET |
| ok2: |
| MOVQ AX, r1+16(FP) |
| MOVQ $0, err+24(FP) |
| RET |
| |
| // func rawSyscallNoError(trap, a1, a2, a3 uintptr) (r1, r2 uintptr) |
| TEXT ·rawSyscallNoError(SB),NOSPLIT,$0-48 |
| MOVQ a1+8(FP), DI |
| MOVQ a2+16(FP), SI |
| MOVQ a3+24(FP), DX |
| MOVQ trap+0(FP), AX // syscall entry |
| SYSCALL |
| MOVQ AX, r1+32(FP) |
| MOVQ DX, r2+40(FP) |
| RET |
| |
| // func gettimeofday(tv *Timeval) (err uintptr) |
| TEXT ·gettimeofday(SB),NOSPLIT,$0-16 |
| MOVQ tv+0(FP), DI |
| MOVQ $0, SI |
| MOVQ runtime·vdsoGettimeofdaySym(SB), AX |
| TESTQ AX, AX |
| JZ fallback |
| CALL AX |
| ret: |
| CMPQ AX, $0xfffffffffffff001 |
| JLS ok7 |
| NEGQ AX |
| MOVQ AX, err+8(FP) |
| RET |
| fallback: |
| MOVL $SYS_gettimeofday, AX |
| SYSCALL |
| JMP ret |
| ok7: |
| MOVQ $0, err+8(FP) |
| RET |
